mirror of
https://github.com/php/php-src.git
synced 2026-04-01 05:02:27 +02:00
24387176d0
- AS_* macros used - Indentation level synced - Obsolete backticks replaced with recommended $(...) (on shells where the "newer" style still doesn't work, for example on Solaris 10 default shell, Autoconf takes care of that by re-executing the script itself)
53 lines
3.0 KiB
Plaintext
53 lines
3.0 KiB
Plaintext
PHP_ARG_ENABLE([cgi],
|
|
[for CGI build],
|
|
[AS_HELP_STRING([--disable-cgi],
|
|
[Disable building CGI version of PHP])],
|
|
[yes],
|
|
[no])
|
|
|
|
if test "$PHP_CGI" != "no"; then
|
|
dnl BSD systems.
|
|
AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[#include <sys/un.h>])
|
|
|
|
AC_MSG_CHECKING([whether cross-process locking is required by accept()])
|
|
AS_CASE([$(uname -sr)],
|
|
[SunOS\ 5.*], [
|
|
AC_MSG_RESULT([yes])
|
|
AC_DEFINE([USE_LOCKING], [1],
|
|
[Define to 1 if cross-process locking is required by 'accept()'.])
|
|
],
|
|
[AC_MSG_RESULT([no])])
|
|
|
|
PHP_ADD_MAKEFILE_FRAGMENT([$abs_srcdir/sapi/cgi/Makefile.frag])
|
|
|
|
dnl Set filename.
|
|
AS_CASE([$host_alias],
|
|
[*cygwin*], [SAPI_CGI_PATH=sapi/cgi/php-cgi.exe],
|
|
[SAPI_CGI_PATH=sapi/cgi/php-cgi])
|
|
|
|
dnl Select SAPI.
|
|
PHP_SELECT_SAPI([cgi],
|
|
[program],
|
|
[cgi_main.c],
|
|
[-DZEND_ENABLE_STATIC_TSRMLS_CACHE=1])
|
|
|
|
AS_CASE([$host_alias],
|
|
[*aix*], [
|
|
AS_VAR_IF([php_sapi_module], [shared], [
|
|
BUILD_CGI="echo '\#! .' > php.sym && echo >>php.sym && nm -BCpg \`echo \$(PHP_GLOBAL_OBJS) \$(PHP_BINARY_OBJS) \$(PHP_CGI_OBJS) | sed 's/\([A-Za-z0-9_]*\)\.lo/.libs\/\1.o/g'\` | \$(AWK) '{ if (((\$\$2 == \"T\") || (\$\$2 == \"D\") || (\$\$2 == \"B\")) && (substr(\$\$3,1,1) != \".\")) { print \$\$3 } }' | sort -u >> php.sym && \$(LIBTOOL) --tag=CC --mode=link \$(CC) -export-dynamic \$(CFLAGS_CLEAN) \$(EXTRA_CFLAGS) \$(EXTRA_LDFLAGS_PROGRAM) \$(LDFLAGS) -Wl,-brtl -Wl,-bE:php.sym \$(PHP_RPATHS) \$(PHP_GLOBAL_OBJS) \$(PHP_BINARY_OBJS) \$(PHP_FASTCGI_OBJS) \$(PHP_CGI_OBJS) \$(EXTRA_LIBS) \$(ZEND_EXTRA_LIBS) -o \$(SAPI_CGI_PATH)"
|
|
], [
|
|
BUILD_CGI="echo '\#! .' > php.sym && echo >>php.sym && nm -BCpg \`echo \$(PHP_GLOBAL_OBJS) \$(PHP_BINARY_OBJS) \$(PHP_CGI_OBJS) | sed 's/\([A-Za-z0-9_]*\)\.lo/\1.o/g'\` | \$(AWK) '{ if (((\$\$2 == \"T\") || (\$\$2 == \"D\") || (\$\$2 == \"B\")) && (substr(\$\$3,1,1) != \".\")) { print \$\$3 } }' | sort -u >> php.sym && \$(LIBTOOL) --tag=CC --mode=link \$(CC) -export-dynamic \$(CFLAGS_CLEAN) \$(EXTRA_CFLAGS) \$(EXTRA_LDFLAGS_PROGRAM) \$(LDFLAGS) -Wl,-brtl -Wl,-bE:php.sym \$(PHP_RPATHS) \$(PHP_GLOBAL_OBJS) \$(PHP_BINARY_OBJS) \$(PHP_FASTCGI_OBJS) \$(PHP_CGI_OBJS) \$(EXTRA_LIBS) \$(ZEND_EXTRA_LIBS) -o \$(SAPI_CGI_PATH)"
|
|
])
|
|
],
|
|
[*darwin*], [
|
|
BUILD_CGI="\$(CC) \$(CFLAGS_CLEAN) \$(EXTRA_CFLAGS) \$(EXTRA_LDFLAGS_PROGRAM) \$(LDFLAGS) \$(NATIVE_RPATHS) \$(PHP_GLOBAL_OBJS:.lo=.o) \$(PHP_BINARY_OBJS:.lo=.o) \$(PHP_FASTCGI_OBJS:.lo=.o) \$(PHP_CGI_OBJS:.lo=.o) \$(PHP_FRAMEWORKS) \$(EXTRA_LIBS) \$(ZEND_EXTRA_LIBS) -o \$(SAPI_CGI_PATH)"
|
|
], [
|
|
BUILD_CGI="\$(LIBTOOL) --tag=CC --mode=link \$(CC) -export-dynamic \$(CFLAGS_CLEAN) \$(EXTRA_CFLAGS) \$(EXTRA_LDFLAGS_PROGRAM) \$(LDFLAGS) \$(PHP_RPATHS) \$(PHP_GLOBAL_OBJS:.lo=.o) \$(PHP_BINARY_OBJS:.lo=.o) \$(PHP_FASTCGI_OBJS:.lo=.o) \$(PHP_CGI_OBJS:.lo=.o) \$(EXTRA_LIBS) \$(ZEND_EXTRA_LIBS) -o \$(SAPI_CGI_PATH)"
|
|
])
|
|
|
|
PHP_SUBST([SAPI_CGI_PATH])
|
|
PHP_SUBST([BUILD_CGI])
|
|
|
|
AC_CONFIG_FILES([sapi/cgi/php-cgi.1])
|
|
fi
|