mirror of
https://github.com/php/php-src.git
synced 2026-03-24 00:02:20 +01:00
dcdcb3cbfe
This replaces the AC_MSG_ERROR with AC_MSG_FAILURE, where appropriate. The AC_MSG_ERROR outputs given message and exits the configure step. The AC_MSG_FAILURE does the same but also automatically outputs additional message "See 'config.log' for more details." which might help directing the user where to look further. The AC_MSG_ERROR is used for errors where current test step isn't logged in the config.log and wouldn't make sense, and AC_MSG_FAILURE is mostly used in cases of library checks, compilation tests, headers checked with AC_CHECK_HEADER* and similar tests that are also logged in the config.log. AC_MSG_ERROR([Sanity check failed.]) output: ``` configure: error: Sanity check failed. ``` AC_MSG_FAILURE([Sanity check failed.]) output: ``` configure: error: in '/path/to/php-src': configure: error: Sanity check failed. See 'config.log' for more details ```
67 lines
2.2 KiB
Plaintext
67 lines
2.2 KiB
Plaintext
PHP_ARG_WITH([snmp],
|
|
[for SNMP support],
|
|
[AS_HELP_STRING([[--with-snmp[=DIR]]],
|
|
[Include SNMP support])])
|
|
|
|
if test "$PHP_SNMP" != "no"; then
|
|
|
|
if test "$PHP_SNMP" = "yes"; then
|
|
AC_PATH_PROG(SNMP_CONFIG,net-snmp-config,,[/usr/local/bin:$PATH])
|
|
else
|
|
SNMP_CONFIG="$PHP_SNMP/bin/net-snmp-config"
|
|
fi
|
|
|
|
if test -x "$SNMP_CONFIG"; then
|
|
SNMP_LIBS=`$SNMP_CONFIG --netsnmp-libs`
|
|
SNMP_LIBS="$SNMP_LIBS `$SNMP_CONFIG --external-libs`"
|
|
SNMP_PREFIX=`$SNMP_CONFIG --prefix`
|
|
snmp_full_version=`$SNMP_CONFIG --version`
|
|
ac_IFS=$IFS
|
|
IFS="."
|
|
set $snmp_full_version
|
|
IFS=$ac_IFS
|
|
SNMP_VERSION=`expr [$]1 \* 1000 + [$]2`
|
|
if test "$SNMP_VERSION" -ge "5003"; then
|
|
if test -n "$SNMP_LIBS" && test -n "$SNMP_PREFIX"; then
|
|
PHP_ADD_INCLUDE([${SNMP_PREFIX}/include])
|
|
PHP_EVAL_LIBLINE([$SNMP_LIBS], [SNMP_SHARED_LIBADD])
|
|
SNMP_LIBNAME=netsnmp
|
|
else
|
|
AC_MSG_ERROR([Could not find the required paths. Please check your net-snmp installation.])
|
|
fi
|
|
else
|
|
AC_MSG_ERROR([Net-SNMP version 5.3 or greater required (detected $snmp_full_version).])
|
|
fi
|
|
else
|
|
AC_MSG_ERROR([Could not find net-snmp-config binary. Please check your net-snmp installation.])
|
|
fi
|
|
|
|
dnl Test build.
|
|
PHP_CHECK_LIBRARY([$SNMP_LIBNAME], [init_snmp],
|
|
[AC_DEFINE([HAVE_SNMP], [1],
|
|
[Define to 1 if the PHP extension 'snmp' is available.])],
|
|
[AC_MSG_FAILURE([SNMP sanity check failed.])],
|
|
[$SNMP_SHARED_LIBADD])
|
|
|
|
dnl Check whether shutdown_snmp_logging() exists.
|
|
PHP_CHECK_LIBRARY([$SNMP_LIBNAME], [shutdown_snmp_logging],
|
|
[AC_DEFINE([HAVE_SHUTDOWN_SNMP_LOGGING], [1], [ ])],
|
|
[],
|
|
[$SNMP_SHARED_LIBADD])
|
|
|
|
dnl Check whether usmHMAC192SHA256AuthProtocol exists.
|
|
PHP_CHECK_LIBRARY([$SNMP_LIBNAME], [usmHMAC192SHA256AuthProtocol],
|
|
[AC_DEFINE([HAVE_SNMP_SHA256], [1], [ ])],
|
|
[],
|
|
[$SNMP_SHARED_LIBADD])
|
|
|
|
dnl Check whether usmHMAC384SHA512AuthProtocol exists.
|
|
PHP_CHECK_LIBRARY([$SNMP_LIBNAME], [usmHMAC384SHA512AuthProtocol],
|
|
[AC_DEFINE([HAVE_SNMP_SHA512], [1], [ ])],
|
|
[],
|
|
[$SNMP_SHARED_LIBADD])
|
|
|
|
PHP_NEW_EXTENSION([snmp], [snmp.c], [$ext_shared])
|
|
PHP_SUBST([SNMP_SHARED_LIBADD])
|
|
fi
|