mirror of
https://github.com/php/php-src.git
synced 2026-03-24 00:02:20 +01:00
435e67e075
As of PHP 8.5 the minimum required SQLite library is 3.7.17, and this removes the following preprocessor macros checks: - HAVE_SQLITE3_CLOSE_V2 (sqlite3_close_v2() function is available since SQLite 3.7.14.) - HAVE_SQLITE3_ERRSTR (sqlite3_errstr() function is available since SQLite 3.7.15) - SQLITE_VERSION_NUMBER should be now always greater than 3006011 (3.6.11).
33 lines
1.1 KiB
Plaintext
33 lines
1.1 KiB
Plaintext
PHP_ARG_WITH([sqlite3],
|
|
[whether to enable the SQLite3 extension],
|
|
[AS_HELP_STRING([--without-sqlite3],
|
|
[Do not include SQLite3 support.])],
|
|
[yes])
|
|
|
|
if test $PHP_SQLITE3 != "no"; then
|
|
PHP_SETUP_SQLITE([SQLITE3_SHARED_LIBADD])
|
|
AC_DEFINE([HAVE_SQLITE3], [1],
|
|
[Define to 1 if the PHP extension 'sqlite3' is available.])
|
|
|
|
PHP_CHECK_LIBRARY([sqlite3], [sqlite3_expanded_sql],
|
|
[AC_DEFINE([HAVE_SQLITE3_EXPANDED_SQL], [1],
|
|
[Define to 1 if SQLite library has the 'sqlite3_expanded_sql' function.])],
|
|
[],
|
|
[$SQLITE3_SHARED_LIBADD])
|
|
|
|
PHP_CHECK_LIBRARY([sqlite3], [sqlite3_load_extension],
|
|
[],
|
|
[AC_DEFINE([SQLITE_OMIT_LOAD_EXTENSION], [1],
|
|
[Define to 1 if SQLite library was compiled with the
|
|
SQLITE_OMIT_LOAD_EXTENSION and does not have the extension support with
|
|
the 'sqlite3_load_extension' function. For usage in the sqlite3 PHP
|
|
extension. See https://www.sqlite.org/compile.html.])],
|
|
[$SQLITE3_SHARED_LIBADD])
|
|
|
|
PHP_NEW_EXTENSION([sqlite3],
|
|
[sqlite3.c],
|
|
[$ext_shared],,
|
|
[-DZEND_ENABLE_STATIC_TSRMLS_CACHE=1])
|
|
PHP_SUBST([SQLITE3_SHARED_LIBADD])
|
|
fi
|