mirror of
https://github.com/php/php-src.git
synced 2026-03-24 00:02:20 +01:00
435e67e075
As of PHP 8.5 the minimum required SQLite library is 3.7.17, and this removes the following preprocessor macros checks: - HAVE_SQLITE3_CLOSE_V2 (sqlite3_close_v2() function is available since SQLite 3.7.14.) - HAVE_SQLITE3_ERRSTR (sqlite3_errstr() function is available since SQLite 3.7.15) - SQLITE_VERSION_NUMBER should be now always greater than 3006011 (3.6.11).
37 lines
1.2 KiB
Plaintext
37 lines
1.2 KiB
Plaintext
PHP_ARG_WITH([pdo-sqlite],
|
|
[for sqlite 3 support for PDO],
|
|
[AS_HELP_STRING([--without-pdo-sqlite],
|
|
[PDO: sqlite 3 support.])],
|
|
[$PHP_PDO])
|
|
|
|
if test "$PHP_PDO_SQLITE" != "no"; then
|
|
PHP_CHECK_PDO_INCLUDES
|
|
|
|
PHP_SETUP_SQLITE([PDO_SQLITE_SHARED_LIBADD])
|
|
|
|
PHP_CHECK_LIBRARY([sqlite3], [sqlite3_column_table_name],
|
|
[AC_DEFINE([HAVE_SQLITE3_COLUMN_TABLE_NAME], [1],
|
|
[Define to 1 if SQLite library was compiled with the
|
|
SQLITE_ENABLE_COLUMN_METADATA and has the 'sqlite3_column_table_name'
|
|
function.])],
|
|
[],
|
|
[$PDO_SQLITE_SHARED_LIBADD])
|
|
|
|
PHP_CHECK_LIBRARY([sqlite3], [sqlite3_load_extension],
|
|
[],
|
|
[AC_DEFINE([PDO_SQLITE_OMIT_LOAD_EXTENSION], [1],
|
|
[Define to 1 if SQLite library was compiled with the
|
|
SQLITE_OMIT_LOAD_EXTENSION and does not have the extension support with
|
|
the 'sqlite3_load_extension' function. For usage in the pdo_sqlite. See
|
|
https://www.sqlite.org/compile.html.])],
|
|
[$PDO_SQLITE_SHARED_LIBADD])
|
|
|
|
PHP_SUBST([PDO_SQLITE_SHARED_LIBADD])
|
|
PHP_NEW_EXTENSION([pdo_sqlite],
|
|
[pdo_sqlite.c sqlite_driver.c sqlite_statement.c sqlite_sql_parser.c],
|
|
[$ext_shared])
|
|
|
|
PHP_ADD_EXTENSION_DEP(pdo_sqlite, pdo)
|
|
PHP_ADD_MAKEFILE_FRAGMENT
|
|
fi
|