mirror of
https://github.com/macintoshplus/mongo-php-driver.git
synced 2026-03-26 18:02:10 +01:00
4177e66bf3
* Do not call AC_PROG_CC_C99 on autoconf 2.70+ * Replace obsolete AC_TRY_COMPILE with AC_COMPILE_IFELSE * Update pkg.m4 to pkg-config-0.29 * Update ax_check_compile_flag.m4 * Update ax_pthread.m4 * Update ax_prototype.m4 and introduce ax_prototype_accept.m4 This also moves the accept() checking to libmongoc/FindDependencies.m4, since it is specific to libmongoc. * PHPC-2272: as_var_copy.m4 is obsolete PHP 7.4 requires autoconf 2.68+ and AS_VAR_COPY was introduced in 2.64
74 lines
2.1 KiB
Plaintext
74 lines
2.1 KiB
Plaintext
# If CFLAGS and CXXFLAGS are unset, default to empty.
|
|
# This is to tell automake not to include '-g' if C{XX,}FLAGS is not set.
|
|
# For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
|
|
if test -z "$CXXFLAGS"; then
|
|
CXXFLAGS=""
|
|
fi
|
|
if test -z "$CFLAGS"; then
|
|
CFLAGS=""
|
|
fi
|
|
|
|
AC_PROG_CC
|
|
AC_PROG_CXX
|
|
|
|
dnl AC_PROG_CC_C99 is previously called in config.m4, but AC_PROG_CC resets CC
|
|
dnl so call it once more to ensure C99 remains enabled
|
|
m4_version_prereq([2.70],,[AC_PROG_CC_C99])
|
|
|
|
# Check that an appropriate C compiler is available.
|
|
c_compiler="unknown"
|
|
AC_LANG_PUSH([C])
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
|
|
#if !(defined(__GNUC__) && !defined(__clang__) && !defined(__INTEL_COMPILER))
|
|
#error Not a supported GCC compiler
|
|
#endif
|
|
#if defined(__GNUC__)
|
|
#define GCC_VERSION (__GNUC__ * 10000 \
|
|
+ __GNUC_MINOR__ * 100 \
|
|
+ __GNUC_PATCHLEVEL__)
|
|
#if GCC_VERSION < 40100
|
|
#error Not a supported GCC compiler
|
|
#endif
|
|
#endif
|
|
])], [c_compiler="gcc"], [])
|
|
|
|
# If our BEGIN_IGNORE_DEPRECATIONS macro won't work, pass
|
|
# -Wno-deprecated-declarations
|
|
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
|
|
#if !defined(__clang__) && defined(__GNUC__)
|
|
#define GCC_VERSION (__GNUC__ * 10000 \
|
|
+ __GNUC_MINOR__ * 100 \
|
|
+ __GNUC_PATCHLEVEL__)
|
|
#if GCC_VERSION < 40600
|
|
#error Does not support deprecation warning pragmas
|
|
#endif
|
|
#endif
|
|
])], [], [STD_CFLAGS="$STD_CFLAGS -Wno-deprecated-declarations"])
|
|
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
|
|
#if defined(__clang__)
|
|
#define CLANG_VERSION (__clang_major__ * 10000 \
|
|
+ __clang_minor__ * 100 \
|
|
+ __clang_patchlevel__)
|
|
#if CLANG_VERSION < 30300
|
|
#error Not a supported Clang compiler
|
|
#endif
|
|
#endif
|
|
])], [c_compiler="clang"], [])
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
|
|
#if !(defined(__SUNPRO_C))
|
|
#error Not a supported Sun compiler
|
|
#endif
|
|
])], [c_compiler="sun"], [])
|
|
|
|
AC_LANG_POP([C])
|
|
|
|
if test "$c_compiler" = "unknown"; then
|
|
AC_MSG_ERROR([Compiler GCC >= 4.1 or Clang >= 3.3 is required for C compilation])
|
|
fi
|
|
|
|
AC_C_CONST
|
|
AC_C_INLINE
|
|
AC_C_TYPEOF
|